-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathmeson.build
132 lines (121 loc) · 3.34 KB
/
meson.build
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
project('gnome-browser-connector',
license: 'GPL-3',
version: run_command(
'python3', '-c',
'from gnome_browser_connector.version import __version__; print(__version__, end="")',
check: true
).stdout(),
)
# Constants
MANIFEST_FILENAME = 'org.gnome.browser_connector.json'
MANIFEST_LEGACY_FILENAME = 'org.gnome.chrome_gnome_shell.json'
# Dependencies
python_module = import('python')
py = python_module.find_installation('python3', required: true, modules: [
'gi'
])
# Configuration used in template files
config = configuration_data()
config.set('bindir', get_option('prefix') / get_option('bindir'))
config.set('python_path', py.path())
# Install scripts
foreach script : ['gnome-browser-connector', 'gnome-browser-connector-host']
configure_file(
input: script + '.py.in',
output: script,
configuration: config,
install_dir: get_option('bindir'),
)
endforeach
# Python module
install_subdir(
'gnome_browser_connector',
install_dir: py.get_install_dir(),
)
# Chrome/Chromium connector manifests
configure_file(
input: 'contrib' / MANIFEST_FILENAME,
output: MANIFEST_FILENAME,
configuration: config,
)
configure_file(
input: [
meson.current_build_dir() / MANIFEST_FILENAME,
'contrib' / MANIFEST_LEGACY_FILENAME,
],
output: MANIFEST_LEGACY_FILENAME,
command: [
'contrib/merge_json.py',
'--output', '@OUTPUT@',
'@INPUT@'
],
)
foreach dir : ['chromium/native-messaging-hosts', 'opt/chrome/native-messaging-hosts']
foreach file : [MANIFEST_FILENAME, MANIFEST_LEGACY_FILENAME]
install_data(
meson.current_build_dir() / file,
install_dir: get_option('sysconfdir') / dir
)
endforeach
endforeach
# Firefox connector manifest
configure_file(
input: [
meson.current_build_dir() / MANIFEST_FILENAME,
'contrib/org.gnome.browser_connector.firefox.json',
],
output: 'firefox-' + MANIFEST_FILENAME,
command: [
'contrib/merge_json.py',
'--delete', 'allowed_origins',
'--output', '@OUTPUT@',
'@INPUT@'
],
)
configure_file(
input: [
meson.current_build_dir() / ('firefox-' + MANIFEST_FILENAME),
'contrib' / MANIFEST_LEGACY_FILENAME,
],
output: 'firefox-' + MANIFEST_LEGACY_FILENAME,
command: [
'contrib/merge_json.py',
'--output', '@OUTPUT@',
'@INPUT@'
],
)
foreach file : [MANIFEST_FILENAME, MANIFEST_LEGACY_FILENAME]
install_data(
meson.current_build_dir() / ('firefox-' + file),
install_dir: get_option('libdir') / 'mozilla/native-messaging-hosts',
rename: file,
)
endforeach
# DBus service
configure_file(
input: 'contrib/org.gnome.BrowserConnector.service.in',
output: 'org.gnome.BrowserConnector.service',
configuration: config,
)
install_data(
meson.current_build_dir() / 'org.gnome.BrowserConnector.service',
install_dir: get_option('datadir') / 'dbus-1/services',
)
# Desktop file
configure_file(
input: 'contrib/org.gnome.BrowserConnector.desktop.in',
output: 'org.gnome.BrowserConnector.desktop',
configuration: config,
)
install_data(
meson.current_build_dir() /'org.gnome.BrowserConnector.desktop',
install_dir: get_option('datadir') / 'applications',
)
# Icons
foreach size : ['16', '48', '128']
install_data(
'contrib/icons' / 'GnomeLogo-' + size + '.png',
install_dir: get_option('datadir') / 'icons/hicolor' / (size + 'x' + size) / 'apps',
rename: 'org.gnome.BrowserConnector.png'
)
endforeach