-
Notifications
You must be signed in to change notification settings - Fork 23
/
Copy pathCMakeLists.txt
108 lines (90 loc) · 3.55 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
cmake_minimum_required(VERSION 3.15)
project(smooth VERSION 1.1.0)
set(CMAKE_CXX_STANDARD 20)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
option(BUILD_EXAMPLES "Build the examples." OFF)
message(STATUS "BUILD_EXAMPLES set to: ${BUILD_EXAMPLES}")
option(BUILD_TESTS "Build the tests." OFF)
message(STATUS "BUILD_TESTS set to: ${BUILD_TESTS}")
# ---------------------------------------------------------------------------------------
# INCLUDES
# ---------------------------------------------------------------------------------------
include(GNUInstallDirs)
include(CMakePackageConfigHelpers)
# ---------------------------------------------------------------------------------------
# DEPENDENCIES
# ---------------------------------------------------------------------------------------
find_package(Eigen3 3.4 REQUIRED)
# ---------------------------------------------------------------------------------------
# CONFIGURATION
# ---------------------------------------------------------------------------------------
configure_file(
${CMAKE_CURRENT_SOURCE_DIR}/config/version.hpp.in
${CMAKE_CURRENT_BINARY_DIR}/include/smooth/version.hpp @ONLY
)
# ---------------------------------------------------------------------------------------
# TARGETS
# ---------------------------------------------------------------------------------------
add_library(smooth INTERFACE)
target_include_directories(
smooth
INTERFACE $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/include>
$<INSTALL_INTERFACE:include>
)
target_link_libraries(smooth INTERFACE Eigen3::Eigen)
# ---------------------------------------------------------------------------------------
# INSTALLATION
# ---------------------------------------------------------------------------------------
# Header files
install(DIRECTORY ${PROJECT_SOURCE_DIR}/include/${PROJECT_NAME}
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/include/smooth/version.hpp
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}
)
# Targets
install(
TARGETS smooth
EXPORT ${PROJECT_NAME}_targets
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
)
# ---------------------------------------------------------------------------------------
# CMAKE CONFIGURATION
# ---------------------------------------------------------------------------------------
set(export_dest_dir ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME})
# Generate TARGETS files
install(
EXPORT ${PROJECT_NAME}_targets
FILE ${PROJECT_NAME}Targets.cmake
NAMESPACE ${PROJECT_NAME}::
DESTINATION ${export_dest_dir}
)
# Generate CONFIG file
configure_package_config_file(
cmake/ConfigTemplate.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
INSTALL_DESTINATION ${export_dest_dir}
NO_SET_AND_CHECK_MACRO
)
# Generate VERSION file
write_basic_package_version_file(
${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Version.cmake
VERSION ${PACKAGE_VERSION}
COMPATIBILITY SameMajorVersion
)
# Install CONFIG and VERSION files
install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Version.cmake
DESTINATION ${export_dest_dir}
)
# ---------------------------------------------------------------------------------------
# EXECUTABLES
# ---------------------------------------------------------------------------------------
if(BUILD_EXAMPLES)
add_subdirectory(examples)
endif()
if(BUILD_TESTS)
enable_testing()
add_subdirectory(tests)
endif()