build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
plugins {
    alias(libs.plugins.gradle.versions.plugin)
    id "jacoco"

    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.kotlin.parcelize) apply false
    alias(libs.plugins.kotlin.kapt) apply false
    alias(libs.plugins.compose.compiler) apply false

    alias(libs.plugins.hilt.android) apply false

    alias(libs.plugins.kotlin.kover)
}

allprojects {
    repositories {
        mavenCentral()
        google()
    }
}

// references https://github.com/ben-manes/gradle-versions-plugin#revisions
tasks.named("dependencyUpdates").configure {
    rejectVersionIf {
        String version = it.candidate.version.toLowerCase(Locale.US)
        version.contains("alpha") || version.contains("beta") || version.contains("rc")
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

kover {
    currentProject {
        createVariant("merged") {
        }
    }
    reports {
        filters {
            excludes {
                androidGeneratedClasses()
                packages("io.viewpoint.moviedatabase.platform.*")
            }
        }
    }
}

dependencies {
    kover(project(':core:model'))
    kover(project(':core:common'))
    kover(project(':core:api'))
    kover(project(':core:resources'))
    kover(project(':core:domain'))
    kover(project(':core:designsystem'))
    kover(project(':core:widget'))

    kover(project(':feature:home'))
    kover(project(':feature:search'))
    kover(project(':feature:setting'))
    kover(project(':feature:common-ui'))

    kover(project(':app'))
}