Fiz Fractais

[AlissonSteffens]

Eu fiz dois algoritmos de Fractais no Portugol, um com o Fractal de Vicsek, e outro com o Triângulo de Sierpinski

Fractal de Vicsek

programa
{
	inclua biblioteca Graficos --> g
	inclua biblioteca Matematica --> m

	funcao inicializar(){
		g.iniciar_modo_grafico(verdadeiro)
		g.definir_dimensoes_janela(1920, 1080)
	}

	funcao desenhar_cruz(inteiro x, inteiro y, inteiro tamanho ){
		inteiro largura = tamanho/5
		g.desenhar_retangulo(x-largura/2, y-tamanho/2, largura, tamanho, falso, verdadeiro)
		g.desenhar_retangulo(x-tamanho/2, y-largura/2, tamanho, largura, falso, verdadeiro)
	}

	funcao fractal(inteiro x, inteiro y, inteiro tamanho, inteiro profundidade){
		desenhar_cruz(x,y,tamanho)
		se(profundidade > 1){
			fractal(x+tamanho/2,y, tamanho/2, profundidade-1)
			fractal(x-tamanho/2,y, tamanho/2, profundidade-1)
			fractal(x,y+tamanho/2, tamanho/2, profundidade-1)
			fractal(x,y-tamanho/2, tamanho/2, profundidade-1)
			
		}
	}
	
	funcao inicio()	
	{
		inicializar()
		enquanto(verdadeiro){
			g.definir_cor(0x333333)
			g.limpar()
			g.definir_cor(0xeeeeee)
			fractal(1920/2,1080/2,1080/2,8)
			g.renderizar()
			
			
		}
	}
}

Triângulo de Sierpinski

programa
{
	inclua biblioteca Graficos --> g
	inclua biblioteca Matematica --> m

	funcao inicializar(){
		g.iniciar_modo_grafico(verdadeiro)
		g.definir_dimensoes_janela(1920, 1080)
	}

	funcao desenhar_triangulo(inteiro x, inteiro y, inteiro tamanho ){
		inteiro pontos[3][2]

		pontos[0][0] = x
		pontos[0][1] = y

		pontos[1][0] = x-tamanho
		pontos[1][1] = y+tamanho*m.raiz(3, 2)

		pontos[2][0] = x+tamanho
		pontos[2][1] = y+tamanho*m.raiz(3, 2)
		g.desenhar_poligono(pontos, verdadeiro)
	}

	funcao fractal_triangular(inteiro x, inteiro y, inteiro tamanho, inteiro profundidade){
		se(profundidade <= 1){
			desenhar_triangulo(x,y,tamanho)
		}senao{
			fractal_triangular(x,y, tamanho/2, profundidade-1)
			fractal_triangular(x-tamanho/2,y+tamanho/2*m.raiz(3,2), tamanho/2, profundidade-1)
			fractal_triangular(x+tamanho/2,y+tamanho/2*m.raiz(3,2), tamanho/2, profundidade-1)
		}
	}
	
	funcao inicio()	
	{
		inicializar()
		enquanto(verdadeiro){
			g.definir_cor(0x333333)
			g.limpar()
			g.definir_cor(0xeeeeee)
			fractal_triangular(1920/2,50,1080/2,10)
			g.renderizar()
			
			
		}
	}
}