build.gradle

plugins {
    id 'org.springframework.boot' version '3.2.3' apply(false)
    id 'io.spring.dependency-management' version '1.1.0' apply(false)
    id 'org.asciidoctor.jvm.convert' version '3.3.2' apply(false)
    id 'java-library'
    id 'jacoco'
    id "org.sonarqube" version "3.4.0.2513" apply(false)
}

allprojects {
    apply plugin: 'java-library'
    apply plugin: 'org.sonarqube'

    group = 'com.woowacourse'
    version = '0.0.1-SNAPSHOT'
    sourceCompatibility = '17'

    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: 'jacoco'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'org.asciidoctor.jvm.convert'

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
        asciidoctorExtensions
    }

    dependencies {
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'

        testImplementation 'org.springframework.boot:spring-boot-starter-test'
    }

    bootJar {
        enabled = false
    }

    jar {
        enabled = true
    }

    test {
        useJUnitPlatform()
        finalizedBy 'jacocoTestReport'
    }

    jacocoTestReport {
        reports {
            html.enabled true
            xml.enabled true
            csv.enabled true
        }
        finalizedBy 'jacocoTestCoverageVerification'
    }

    jacocoTestCoverageVerification {
        violationRules {
            rule {
                enabled = true
                element = 'CLASS'

                limit {
                    counter = 'LINE'
                    value = 'COVEREDRATIO'
                    minimum = 0.0
                }
            }
            rule {
                enabled = true;
                element = 'BUNDLE'

                limit {
                    counter = 'CLASS'
                    value = 'COVEREDRATIO'
                    minimum = 0.0
                }
            }
        }
    }
}

sonarqube {
    properties {
        property "sonar.projectKey", "The-Fellowship-of-the-matzip_mat.zip-back"
        property "sonar.organization", "the-fellowship-of-the-matzip"
        property "sonar.host.url", "https://sonarcloud.io"
        property 'sonar.coverage.jacoco.xmlReportPaths', '${buildDir}/reports/jacoco/test/jacocoTestReport.xml'
    }
}