-
Notifications
You must be signed in to change notification settings - Fork 56
/
Copy pathkrylov_processes.jl
459 lines (393 loc) · 11.5 KB
/
krylov_processes.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
export hermitian_lanczos, nonhermitian_lanczos, arnoldi, golub_kahan, saunders_simon_yip, montoison_orban
"""
V, T = hermitian_lanczos(A, b, k)
#### Input arguments
* `A`: a linear operator that models a Hermitian matrix of dimension n;
* `b`: a vector of length n;
* `k`: the number of iterations of the Hermitian Lanczos process.
#### Output arguments
* `V`: a dense n × (k+1) matrix;
* `T`: a sparse (k+1) × k tridiagonal matrix.
#### Reference
* C. Lanczos, [*An Iteration Method for the Solution of the Eigenvalue Problem of Linear Differential and Integral Operators*](https://doi.org/10.6028/jres.045.026), Journal of Research of the National Bureau of Standards, 45(4), pp. 225--280, 1950.
"""
function hermitian_lanczos(A, b::AbstractVector{FC}, k::Int) where FC <: FloatOrComplex
m, n = size(A)
R = real(FC)
S = ktypeof(b)
M = vector_to_matrix(S)
colptr = zeros(Int, k+1)
rowval = zeros(Int, 3k-1)
nzval = zeros(R, 3k-1)
colptr[1] = 1
rowval[1] = 1
rowval[2] = 2
for i = 1:k
colptr[i+1] = 3i
if i ≥ 2
pos = colptr[i]
rowval[pos] = i-1
rowval[pos+1] = i
rowval[pos+2] = i+1
end
end
V = M(undef, n, k+1)
T = SparseMatrixCSC(k+1, k, colptr, rowval, nzval)
for i = 1:k
vᵢ = view(V,:,i)
vᵢ₊₁ = q = view(V,:,i+1)
if i == 1
βᵢ = @knrm2(n, b)
vᵢ .= b ./ βᵢ
end
mul!(q, A, vᵢ)
αᵢ = @kdotr(n, vᵢ, q)
T[i,i] = αᵢ
@kaxpy!(n, -αᵢ, vᵢ, q)
if i ≥ 2
vᵢ₋₁ = view(V,:,i-1)
βᵢ = T[i,i-1]
T[i-1,i] = βᵢ
@kaxpy!(n, -βᵢ, vᵢ₋₁, q)
end
βᵢ₊₁ = @knrm2(n, q)
T[i+1,i] = βᵢ₊₁
vᵢ₊₁ .= q ./ βᵢ₊₁
end
return V, T
end
"""
V, T, U, Tᴴ = nonhermitian_lanczos(A, b, c, k)
#### Input arguments
* `A`: a linear operator that models a square matrix of dimension n;
* `b`: a vector of length n;
* `c`: a vector of length n;
* `k`: the number of iterations of the non-Hermitian Lanczos process.
#### Output arguments
* `V`: a dense n × (k+1) matrix;
* `T`: a sparse (k+1) × k tridiagonal matrix;
* `U`: a dense n × (k+1) matrix;
* `Tᴴ`: a sparse (k+1) × k tridiagonal matrix.
#### Reference
* C. Lanczos, [*An Iteration Method for the Solution of the Eigenvalue Problem of Linear Differential and Integral Operators*](https://doi.org/10.6028/jres.045.026), Journal of Research of the National Bureau of Standards, 45(4), pp. 225--280, 1950.
"""
function nonhermitian_lanczos(A, b::AbstractVector{FC}, c::AbstractVector{FC}, k::Int) where FC <: FloatOrComplex
m, n = size(A)
Aᴴ = A'
S = ktypeof(b)
M = vector_to_matrix(S)
colptr = zeros(Int, k+1)
rowval = zeros(Int, 3k-1)
nzval_T = zeros(FC, 3k-1)
nzval_Tᴴ = zeros(FC, 3k-1)
colptr[1] = 1
rowval[1] = 1
rowval[2] = 2
for i = 1:k
colptr[i+1] = 3i
if i ≥ 2
pos = colptr[i]
rowval[pos] = i-1
rowval[pos+1] = i
rowval[pos+2] = i+1
end
end
V = M(undef, n, k+1)
U = M(undef, n, k+1)
T = SparseMatrixCSC(k+1, k, colptr, rowval, nzval_T)
Tᴴ = SparseMatrixCSC(k+1, k, colptr, rowval, nzval_Tᴴ)
for i = 1:k
vᵢ = view(V,:,i)
uᵢ = view(U,:,i)
vᵢ₊₁ = q = view(V,:,i+1)
uᵢ₊₁ = p = view(U,:,i+1)
if i == 1
cᴴb = @kdot(n, c, b)
βᵢ = √(abs(cᴴb))
γᵢ = cᴴb / βᵢ
vᵢ .= b ./ βᵢ
uᵢ .= c ./ conj(γᵢ)
end
mul!(q, A , vᵢ)
mul!(p, Aᴴ, uᵢ)
if i ≥ 2
vᵢ₋₁ = view(V,:,i-1)
uᵢ₋₁ = view(U,:,i-1)
βᵢ = T[i,i-1]
γᵢ = T[i-1,i]
@kaxpy!(n, - γᵢ , vᵢ₋₁, q)
@kaxpy!(n, -conj(βᵢ), uᵢ₋₁, p)
end
αᵢ = @kdot(n, uᵢ, q)
T[i,i] = αᵢ
Tᴴ[i,i] = conj(αᵢ)
@kaxpy!(m, - αᵢ , vᵢ, q)
@kaxpy!(n, -conj(αᵢ), uᵢ, p)
pᴴq = @kdot(n, p, q)
βᵢ₊₁ = √(abs(pᴴq))
γᵢ₊₁ = pᴴq / βᵢ₊₁
vᵢ₊₁ .= q ./ βᵢ₊₁
uᵢ₊₁ .= p ./ conj(γᵢ₊₁)
T[i+1,i] = βᵢ₊₁
Tᴴ[i+1,i] = conj(γᵢ₊₁)
if i ≤ k-1
T[i,i+1] = γᵢ₊₁
Tᴴ[i,i+1] = conj(βᵢ₊₁)
end
end
return V, T, U, Tᴴ
end
"""
V, H = arnoldi(A, b, k)
#### Input arguments
* `A`: a linear operator that models a square matrix of dimension n;
* `b`: a vector of length n;
* `k`: the number of iterations of the Arnoldi process.
#### Output arguments
* `V`: a dense n × (k+1) matrix;
* `H`: a sparse (k+1) × k upper Hessenberg matrix.
#### Reference
* W. E. Arnoldi, [*The principle of minimized iterations in the solution of the matrix eigenvalue problem*](https://doi.org/10.1090/qam/42792), Quarterly of Applied Mathematics, 9, pp. 17--29, 1951.
"""
function arnoldi(A, b::AbstractVector{FC}, k::Int) where FC <: FloatOrComplex
m, n = size(A)
S = ktypeof(b)
M = vector_to_matrix(S)
nnz = div(k*(k+1), 2) + k
colptr = zeros(Int, k+1)
rowval = zeros(Int, nnz)
nzval = zeros(FC, nnz)
colptr[1] = 1
for i = 1:k
pos = colptr[i]
colptr[i+1] = pos+i+1
for j = 1:i+1
rowval[pos+j-1] = j
end
end
V = M(undef, n, k+1)
H = SparseMatrixCSC(k+1, k, colptr, rowval, nzval)
for i = 1:k
vᵢ = view(V,:,i)
vᵢ₊₁ = q = view(V,:,i+1)
if i == 1
β = @knrm2(n, b)
vᵢ .= b ./ β
end
mul!(q, A, vᵢ)
for j = 1:i
vⱼ = view(V,:,j)
H[j,i] = @kdot(n, vⱼ, q)
@kaxpy!(n, -H[j,i], vⱼ, q)
end
H[i+1,i] = @knrm2(n, q)
vᵢ₊₁ .= q ./ H[i+1,i]
end
return V, H
end
"""
V, U, L = golub_kahan(A, b, k)
#### Input arguments
* `A`: a linear operator that models a matrix of dimension m × n;
* `b`: a vector of length m;
* `k`: the number of iterations of the Golub-Kahan process.
#### Output arguments
* `V`: a dense n × (k+1) matrix;
* `U`: a dense m × (k+1) matrix;
* `L`: a sparse (k+1) × (k+1) lower bidiagonal matrix.
#### Reference
* G. H. Golub and W. Kahan, [*Calculating the Singular Values and Pseudo-Inverse of a Matrix*](https://doi.org/10.1137/0702016), SIAM Journal on Numerical Analysis, 2(2), pp. 225--224, 1965.
"""
function golub_kahan(A, b::AbstractVector{FC}, k::Int) where FC <: FloatOrComplex
m, n = size(A)
R = real(FC)
Aᴴ = A'
S = ktypeof(b)
M = vector_to_matrix(S)
colptr = zeros(Int, k+2)
rowval = zeros(Int, 2k+1)
nzval = zeros(R, 2k+1)
colptr[1] = 1
for i = 1:k
pos = colptr[i]
colptr[i+1] = pos+2
rowval[pos] = i
rowval[pos+1] = i+1
end
rowval[2k+1] = k+1
colptr[k+2] = 2k+2
V = M(undef, n, k+1)
U = M(undef, m, k+1)
L = SparseMatrixCSC(k+1, k+1, colptr, rowval, nzval)
for i = 1:k
uᵢ = view(U,:,i)
vᵢ = view(V,:,i)
uᵢ₊₁ = q = view(U,:,i+1)
vᵢ₊₁ = p = view(V,:,i+1)
if i == 1
wᵢ = vᵢ
βᵢ = @knrm2(m, b)
uᵢ .= b ./ βᵢ
mul!(wᵢ, Aᴴ, uᵢ)
αᵢ = @knrm2(n, wᵢ)
L[1,1] = αᵢ
vᵢ .= wᵢ ./ αᵢ
end
mul!(q, A, vᵢ)
αᵢ = L[i,i]
@kaxpy!(m, -αᵢ, uᵢ, q)
βᵢ₊₁ = @knrm2(m, q)
uᵢ₊₁ .= q ./ βᵢ₊₁
mul!(p, Aᴴ, uᵢ₊₁)
@kaxpy!(n, -βᵢ₊₁, vᵢ, p)
αᵢ₊₁ = @knrm2(n, p)
vᵢ₊₁ .= p ./ αᵢ₊₁
L[i+1,i] = βᵢ₊₁
L[i+1,i+1] = αᵢ₊₁
end
return V, U, L
end
"""
V, T, U, Tᴴ = saunders_simon_yip(A, b, c, k)
#### Input arguments
* `A`: a linear operator that models a matrix of dimension m × n;
* `b`: a vector of length m;
* `c`: a vector of length n;
* `k`: the number of iterations of the Saunders-Simon-Yip process.
#### Output arguments
* `V`: a dense m × (k+1) matrix;
* `T`: a sparse (k+1) × k tridiagonal matrix;
* `U`: a dense n × (k+1) matrix;
* `Tᴴ`: a sparse (k+1) × k tridiagonal matrix.
#### Reference
* M. A. Saunders, H. D. Simon, and E. L. Yip, [*Two Conjugate-Gradient-Type Methods for Unsymmetric Linear Equations*](https://doi.org/10.1137/0725052), SIAM Journal on Numerical Analysis, 25(4), pp. 927--940, 1988.
"""
function saunders_simon_yip(A, b::AbstractVector{FC}, c::AbstractVector{FC}, k::Int) where FC <: FloatOrComplex
m, n = size(A)
Aᴴ = A'
S = ktypeof(b)
M = vector_to_matrix(S)
colptr = zeros(Int, k+1)
rowval = zeros(Int, 3k-1)
nzval_T = zeros(FC, 3k-1)
nzval_Tᴴ = zeros(FC, 3k-1)
colptr[1] = 1
rowval[1] = 1
rowval[2] = 2
for i = 1:k
colptr[i+1] = 3i
if i ≥ 2
pos = colptr[i]
rowval[pos] = i-1
rowval[pos+1] = i
rowval[pos+2] = i+1
end
end
V = M(undef, m, k+1)
U = M(undef, n, k+1)
T = SparseMatrixCSC(k+1, k, colptr, rowval, nzval_T)
Tᴴ = SparseMatrixCSC(k+1, k, colptr, rowval, nzval_Tᴴ)
for i = 1:k
vᵢ = view(V,:,i)
uᵢ = view(U,:,i)
vᵢ₊₁ = q = view(V,:,i+1)
uᵢ₊₁ = p = view(U,:,i+1)
if i == 1
β = @knrm2(m, b)
γ = @knrm2(n, c)
vᵢ .= b ./ β
uᵢ .= c ./ γ
end
mul!(q, A , uᵢ)
mul!(p, Aᴴ, vᵢ)
if i ≥ 2
vᵢ₋₁ = view(V,:,i-1)
uᵢ₋₁ = view(U,:,i-1)
βᵢ = T[i,i-1]
γᵢ = T[i-1,i]
@kaxpy!(m, -γᵢ, vᵢ₋₁, q)
@kaxpy!(n, -βᵢ, uᵢ₋₁, p)
end
αᵢ = @kdot(m, vᵢ, q)
T[i,i] = αᵢ
Tᴴ[i,i] = conj(αᵢ)
@kaxpy!(m, - αᵢ , vᵢ, q)
@kaxpy!(n, -conj(αᵢ), uᵢ, p)
βᵢ₊₁ = @knrm2(m, q)
γᵢ₊₁ = @knrm2(n, p)
vᵢ₊₁ .= q ./ βᵢ₊₁
uᵢ₊₁ .= p ./ γᵢ₊₁
T[i+1,i] = βᵢ₊₁
Tᴴ[i+1,i] = conj(γᵢ₊₁)
if i ≤ k-1
T[i,i+1] = γᵢ₊₁
Tᴴ[i,i+1] = conj(βᵢ₊₁)
end
end
return V, T, U, Tᴴ
end
"""
V, H, U, F = montoison_orban(A, B, b, c, k)
#### Input arguments
* `A`: a linear operator that models a matrix of dimension m × n;
* `B`: a linear operator that models a matrix of dimension n × m;
* `b`: a vector of length m;
* `c`: a vector of length n;
* `k`: the number of iterations of the Montoison-Orban process.
#### Output arguments
* `V`: a dense m × (k+1) matrix;
* `H`: a sparse (k+1) × k upper Hessenberg matrix;
* `U`: a dense n × (k+1) matrix;
* `F`: a sparse (k+1) × k upper Hessenberg matrix.
#### Reference
* A. Montoison and D. Orban, [*GPMR: An Iterative Method for Unsymmetric Partitioned Linear Systems*](https://dx.doi.org/10.13140/RG.2.2.24069.68326), Cahier du GERAD G-2021-62, GERAD, Montréal, 2021.
"""
function montoison_orban(A, B, b::AbstractVector{FC}, c::AbstractVector{FC}, k::Int) where FC <: FloatOrComplex
m, n = size(A)
S = ktypeof(b)
M = vector_to_matrix(S)
nnz = div(k*(k+1), 2) + k
colptr = zeros(Int, k+1)
rowval = zeros(Int, nnz)
nzval_H = zeros(FC, nnz)
nzval_F = zeros(FC, nnz)
colptr[1] = 1
for i = 1:k
pos = colptr[i]
colptr[i+1] = pos+i+1
for j = 1:i+1
rowval[pos+j-1] = j
end
end
V = M(undef, m, k+1)
U = M(undef, n, k+1)
H = SparseMatrixCSC(k+1, k, colptr, rowval, nzval_H)
F = SparseMatrixCSC(k+1, k, colptr, rowval, nzval_F)
for i = 1:k
vᵢ = view(V,:,i)
uᵢ = view(U,:,i)
vᵢ₊₁ = q = view(V,:,i+1)
uᵢ₊₁ = p = view(U,:,i+1)
if i == 1
β = @knrm2(m, b)
γ = @knrm2(n, c)
vᵢ .= b ./ β
uᵢ .= c ./ γ
end
mul!(q, A, uᵢ)
mul!(p, B, vᵢ)
for j = 1:i
vⱼ = view(V,:,j)
uⱼ = view(U,:,j)
H[j,i] = @kdot(m, vⱼ, q)
@kaxpy!(n, -H[j,i], vⱼ, q)
F[j,i] = @kdot(n, uⱼ, p)
@kaxpy!(m, -F[j,i], uⱼ, p)
end
H[i+1,i] = @knrm2(m, q)
vᵢ₊₁ .= q ./ H[i+1,i]
F[i+1,i] = @knrm2(n, p)
uᵢ₊₁ .= p ./ F[i+1,i]
end
return V, H, U, F
end